enneper[u_,v_] :={ 3 u + 3 u v^2 - u^3, -3 v - 3 u^2 v + v^3, 3 ( u^2 - v^2 )}

Enneper 曲面を与える写像を enneper[u,v] と定義する．

puu[f_,u_,v_]:= D[f[uu,v], uu] /. uu->u

曲面 f を第１の変数 u で微分する．

pvv[f_,u_,v_]:= D[f[u,vv], vv] /. vv->v

曲面 f を第２の変数 v で微分する．

n[f_][u_,v_] := Cross[ puu[f,u,v], pvv[f,u,v] ] / Sqrt[ Cross[ puu[f,u,v], pvv[f,u,v] ]. Cross[ puu[f,u,v], pvv[f,u,v] ] ]

曲面 f の単位法ベクトル場を n[f][u,v] と定義する．

Simplify[ n[enneper][u,v] ]

Enneper 曲面の単位法ベクトル場を計算する．

ParametricPlot3D[Evaluate[n[enneper][u,v]], {u,-2,2},{v,-2,2}, PlotRange->All]

Enneper 曲面の単位法ベクトル場がどのくらいの範囲を動いたかを見る．

ee[f_][u_,v_] := D[f[uu,vv], uu]. D[f[uu,vv], uu] /. {uu->u, vv->v}

曲面 f の第１基本量の (1,1) 成分を ee[f][u,v] と定義する．

ff[f_][u_,v_]:= D[f[uu,vv], uu]. D[f[uu,vv], vv] /. {uu->u, vv->v}

曲面 f の第１基本量の (1,2) 成分を ff[f][u,v] と定義する．

gg[f_][u_,v_]:= D[f[uu,vv], vv]. D[f[uu,vv], vv] /. {uu->u, vv->v}

曲面 f の第１基本量の (2,2) 成分を gg[f][u,v] と定義する．

ee[enneper][u,v]

Enneper 曲面 の第１基本量の (1,1) 成分を計算する．

Simplify[%]

直前の結果を整理する．

Simplify[ ff[enneper][u,v] ]

Enneper 曲面 の第１基本量の (1,2) 成分を計算する．

Simplify[ gg[enneper][u,v] ]

Enneper 曲面 の第１基本量の (2,2) 成分を計算する．

{{Simplify[ ee[enneper][u,v] ], Simplify[ ff[enneper][u,v] ]}, {Simplify[ ff[enneper][u,v] ], Simplify[ gg[enneper][u,v] ]}}
MatrixForm[%]

Enneper 曲面 の第１基本量を行列の形で表示させる．

ll[f_][u_,v_]:= (D[f[uu,v], {uu,2}] /. uu->u) . n[f][u,v]

曲面 f の第２基本量の (1,1) 成分を ll[f][u,v] と定義する．

mm[f_][u_,v_]:= ( D[( D[f[uu,vv], uu] /. uu->u ), vv] /. vv->v ) . n[f][u,v]

曲面 f の第２基本量の (1,2) 成分を mm[f][u,v] と定義する．

nn[f_][u_,v_]:= (D[f[u,vv], {vv,2}] /. vv->v) . n[f][u,v]

曲面 f の第２基本量の (2,2) 成分を nn[f][u,v] と定義する．

Simplify[ ll[enneper][u,v] ]

Enneper 曲面 の第２基本量の (1,1) 成分を計算する．

Simplify[ mm[enneper][u,v] ]

Enneper 曲面 の第２基本量の (1,2) 成分を計算する．

Simplify[ nn[enneper][u,v] ]

Enneper 曲面 の第２基本量の (2,2) 成分を計算する．

MatrixForm[{{Simplify[ ll[enneper][u,v] ], Simplify[ mm[enneper][u,v] ]},{Simplify[ mm[enneper][u,v] ], Simplify[ nn[enneper][u,v] ]}}]

Enneper 曲面 の第２基本量を行列の形で表示させる．

gausscurv[f_][u_,v_]:= ( ll[f][u,v] nn[f][u,v] - mm[f][u,v]^2 ) / ( ee[f][u,v] gg[f][u,v] - ff[f][u,v]^2 )

曲面 f の Gauss 曲率を gausscurv[f][u,v] と定義する．

meancurv[f_][u_,v_]:= (1/2) ( ee[f][u,v] nn[f][u,v] - 2 ff[f][u,v] mm[f][u,v] + gg[f][u,v] ll[f][u,v] ) / ( ee[f][u,v] gg[f][u,v] - ff[f][u,v]^2 )

曲面 f の 平均曲率を meancurv[f][u,v] と定義する．

Simplify[ gausscurv[enneper][u,v] ]

Enneper 曲面の Gauss 曲率を計算する．

Simplify[ meancurv[enneper][u,v] ]

Enneper 曲面の平均曲率を計算する．

Back to FURUHATA's Home Page